Go to English page

ViaThinkSoft CodeLib

Dieser Artikel befindet sich in:
CodeLibHowTos

Beispiel: Verhindern, dass "Connected = True" in *.dfm Dateien vorkommt.

Es muss folgende Datei angelegt werden: C:\Repositories\...\Hooks\pre-commit.bat

@echo off

SET PATH=%PATH%;C:\Program Files\VisualSVN Server\bin\

setlocal enableextensions EnableDelayedExpansion

for /f "tokens=1,* usebackq" %%i in (`svnlook changed -t %2 %1`) do (
     for %%A in ("A", "U") do if "%%i"==%%A (
          set "changetype=%%i"
          set "filename=%%j"
          if /I "!filename:~-3!"=="dfm" (
               svnlook cat -t %2 %1 "!filename!" | findstr /C:"ConnectionString" > NUL
               if not errorlevel 1 (
                    echo -------------------------------------------- >&2
                    echo VORAB-PRÜFUNG FEHLGESCHLAGEN! >&2
                    echo Es wurde vergessen, ein ConnectionString-Attribut zu entfernen! >&2
                    echo !filename! >&2
                    echo -------------------------------------------- >&2
                    exit 1
               )

          )
     )
)
Daniel Marschall
ViaThinkSoft Mitbegründer, Security Management
ViaThinkSoft Co-Founder, Security Management